Kør din flash movie baglæns

hva man kan bruge det til !? - man kan lave en menu med functionelle rollovers på 11.52 sekunder - http://thonbo.com/download/menu_in10sec/

min kode er lidt mere gennem arbejded :

//force movieClip back to frame 1
MovieClip.prototype.goBack = function () {
  this.onEnterFrame = function () {
    this._currentframe > 1 ? this.prevFrame () : delete this.onEnterFrame;
  };
};
//force movieClip forward to last frame
MovieClip.prototype.goForward = function () {
  this.onEnterFrame = function () {
    this._currentframe < this._totalframes ? this.nextFrame () : delete this.onEnterFrame;
  };
};
// basic rollOver rollOut function
MovieClip.prototype.mcRollOver = function () {
  this.stop ();
  this.onRollOver = function () {
    if (!this.locked) {
      this.goForward ();
    }
  };
  this.onRollOut = function () {
    if (!this.locked) {
      this.goBack ();
    }
  };
};
//SELECTION CONTROLLER /////////////////////
MovieClip.prototype.makeSelection = function () {
  newSelection = this;
  this.locked = true;
  if (newSelection._currentframe != newSelection._totalframes) {
    newSelection.goForward ();
  } else {
    trace ("stoppped");
    stop ();
  }
  oldSelection.goBack ();
  oldSelection.locked = false;
  oldSelection = newSelection;
};

jeg omtaler funktionaliteten her:
http://flashforum.dk/forum/actionscript/actionscript-3/kasser#comment-18408

- jeg har også en as3 version som man bare skal loade som et object extended by movieclip

package {
 
  // author: Philip Thonbo
  // Thonbo.com
  
  import flash.display.MovieClip;
  import flash.events.MouseEvent;
  import flash.events.Event;
 
  public class McRollOver extends MovieClip {
 
    public static  var newSelection:MovieClip;
    public static  var oldSelection:MovieClip;
    public var turnedOff:Boolean = false
    
    public var rollState:String = "off"
    
    public function McRollOver ():void {
      stop ();
      this.enabled = true;
      this.buttonMode = true;
      addEventListener (MouseEvent.MOUSE_OVER, m_Over);
      addEventListener (MouseEvent.MOUSE_OUT, m_Out);
      
    }
    private function m_Over (e:MouseEvent):void {
      e.currentTarget.goForward ();
    }
    private function m_Out (e:MouseEvent):void {
      e.currentTarget.goBack ();
    }
    public function turnOff ():void {
        this.turnedOff = true
        this.buttonMode = false;
        removeEventListener (MouseEvent.MOUSE_OVER, m_Over);
        removeEventListener (MouseEvent.MOUSE_OUT, m_Out);
    }
    
    public function goBack ():void {
      if (this.enabled) {
        this.rollState = "out"
        this.removeEventListener (Event.ENTER_FRAME, go_Forward);
        this.addEventListener (Event.ENTER_FRAME, go_Back);
      }
    }
    public function goForward ():void {
      if (this.enabled) {
        this.rollState = "in"
        this.removeEventListener (Event.ENTER_FRAME, go_Back);
        this.addEventListener (Event.ENTER_FRAME, go_Forward);
      }
    }
    public function killRoll () {
      this.removeEventListener (Event.ENTER_FRAME, go_Back);
      this.removeEventListener (Event.ENTER_FRAME, go_Forward);
    }
    private function go_Back (e:Event):void {
      e.currentTarget.currentFrame > 1 ? e.currentTarget.prevFrame() : e.currentTarget.removeEventListener(Event.ENTER_FRAME, go_Back);
    }
    private function go_Forward (e:Event):void {
      e.currentTarget.currentFrame < e.currentTarget.totalFrames ? e.currentTarget.nextFrame() : e.currentTarget.removeEventListener(Event.ENTER_FRAME, go_Forward);
    }
    public function lockThis ():void {
      newSelection = this;
      if (!newSelection.turnedOff) {
        newSelection.enabled = false;
      }
      if (newSelection.currentFrame != newSelection.totalFrames) {
        newSelection.goForward ();
      } else {
        newSelection.stop ();
      }
      if (oldSelection != null) {
        if (!oldSelection.turnedOff) {
          oldSelection.enabled = true;
        }
        //oldSelection.goBack ();
        oldSelection.gotoAndStop(1);
      }
      oldSelection = newSelection;
 
    }
    public function mcSetFocus ():void {
      this.lockThis ();
    }
    public function mcGetFocus ():MovieClip {
      return McRollOver.oldSelection;
    }
  }
}

3 kommentarer

meget fint, men ganske nytteløst
jeg mener, det er da godt nok, men hvor tit får du brug for det? xD

Hej Bjeld, det er noget i stil med dette jeg har brug for. I går lavede jeg en ud fra en tot. men den virkede kun hvis jeg holdte flashplayeren på flashplayer 5. Det jeg har bug for er as2 kode der "rewinder" ind til den bliver bedt om at stoppe på etbestemt mc.

Min film jeg gerne vil rewinde ligger i et mc sammen med to knapper 1 til frem af og en til tilbage!

Det er sikkert det din kode gør her også, men jeg kan ikke få det implemnteret så det virker. skal det hele ligge i firstframe script? eller på mc og knapper?

Du har ikke evt. en fla man kan se med det i?

På forhånd tak.

Jess